Re: [sc-users] Pattern

[Daniel Mayer <daniel-mayer@xxxxxxxx>]

The original post was only visible on nabble:

http://new-supercollider-mailing-lists-forums-use-these.2681727.n2.nabble.com/Pattern-td7629661.html

>yo, people, mind helping me out a bit? 
>I was working with manipulating running patterns, however now i got onto a problem. 
>i need to change the length of a Pseries, but it doesnt seem to work. im not 100% sure for the reason, even though i might have some >ideas. either way i dont find a fix for this problem. 
>a simple example would be: 

>~c=4; 
>( 
>Pbind( 
>        \degree, Pn(Pseries(0,1,~c),inf), 
>        \dur, 0.25, 
>).play; 
>) 
>~c=2; //now changing the ~c doesnt do anything while the pattern is still running 
>Thanks~!         


These are the main lib variants I came up with

~c = 4

(
Pbind(
	\degree, Pn(Plazy { Pseries(0, 1, ~c) }),
	\dur, 0.25,
).play;
)

~c = 2


// this a nice trick with many patterns: the 'repeats' argument can be a Function / Stream

(
Pbind(
	\degree, Pn(Pseries(0, 1, { ~c })),
	\dur, 0.25,
).play;
)

~c = 1


BTW: never set ~c to 0 in such contexts, this freezes SC !

Then, as mentioned Pdef patterns are a further option.

You could also check out PLx patterns from miSCellaneous lib,
they are designed for replacement of environmental variables:


(
~c = 3;

Pbind(
	\degree, Pn(PLseries(0, 1, \c)),
	\dur, 0.25,
).play;
)

~c = 4;


Regards

Daniel

----------------------------------------------------
http://daniel-mayer.at/software_en.htm
----------------------------------------------------







_______________________________________________
sc-users mailing list

info (subscription, etc.): http://www.birmingham.ac.uk/facilities/ea-studios/research/supercollider/mailinglist.aspx
archive: https://listarc.bham.ac.uk/marchives/sc-users/
search: https://listarc.bham.ac.uk/lists/sc-users/search/