Re: [sc-users] Patch and Variations 1

[Justin Glenn Smith <noisesmith@xxxxxxxxx>]

I've heard of acid jazz, but acid free-jazz?
(
play {
  var saw_array, filter_in, sin_freq, z, drum, hat, drum_pulse, hat_pulse;
  drum_pulse = SinOsc.kr(Dust.kr(3, 0.31, 0.45), 0, 2, 2);
  hat_pulse = SinOsc.kr(Dust.kr(12, 0.5, 1), 0, 4, 8);
  drum = SinOsc.ar(60, 0, Decay.ar(Impulse.ar(drum_pulse), 0.4, 4)).tanh;
  hat = WhiteNoise.ar(Decay.ar(Impulse.ar(hat_pulse, 0.75), 0.02)) * 0.7;
  saw_array = LFSaw.ar(drum_pulse/hat_pulse*[1, 0.99], [0, 0.6], 1000, 12000);
  filter_in =  Mix((saw_array).trunc([400,600])*[1,-1]);
  sin_freq = OnePole.ar(filter_in,-0.7);
  z = (Saw.ar(sin_freq, 10)**5).tanh*0.5;
  drum + hat + ((MoogFF.ar(z,saw_array+1050,3.5)*3).distort*0.3)!2;
}
)

Jonatan Liljedahl wrote:
> I made it into an acid tune :)
> 
> (
> play {
> var saw_array, filter_in, sin_freq, z,drum,hat;
> drum = SinOsc.ar(60,0,Decay.ar(Impulse.ar(2),0.4,4)).tanh;
> hat = WhiteNoise.ar(Decay.ar(Impulse.ar(2,0.5),0.02))*0.3;
> saw_array = LFSaw.ar([1,0.99],[0,0.6],1000);
> filter_in =  Mix((saw_array+12000).trunc([400,600])*[1,-1]);
> sin_freq = OnePole.ar(filter_in,-0.7);
> z = SinOsc.ar(sin_freq, 0, 3).tanh*0.5;
> drum + hat + ((MoogFF.ar(z,saw_array+1050,3.5)*3).distort*0.3)!2;
> }
> )
> 
> Batuhan Bozkurt wrote:
>> Evolutionary art is always cool. :) Here is my part.
>>
>> (
>> play {
>> var saw_array, filter_in, sin_freq, z;
>>
>> saw_array =
>> LFSaw.ar([1,0.99],[0,0.6],1000,12000).trunc([400,600])*[1,-1];
>> filter_in =  Mix(saw_array);
>> sin_freq = OnePole.ar(filter_in,-0.7);
>> z = SinOsc.ar(sin_freq, 0, 3).tanh*0.5;
>>
>> {PitchShift.ar(z, 2.1, 1, 0.01, 0.01)}!2;
>> }
>> )
>>
>> Best,
>> Batuhan Bozkurt
>> /* http://www.earslap.com */
>>
>>
>>
>>
>> On Dec 25, 2009, at 11:00 AM, Steve Bradley wrote:
>>
>>>
>>> Hello Supercollider users,
>>>
>>> I thought that I would try something for fun on here. I saw this done
>>> before
>>> with Supercollider on a different website where someone posted a
>>> patch and
>>> invited other people to change and build upon it to make something
>>> new and
>>> completely different. I decided to use Lance Putnam`s one liner from the
>>> audio/code examples from the Supercollider website as a starting
>>> point. I
>>> had previously asked about this particular instrument a few months
>>> ago when
>>> I was first starting to learn Supercollider and now that I have
>>> learned some
>>> stuff I thought I would revisit it.
>>>
>>> Here is his original code:
>>>
>>> (
>>> play {
>>> var saw_array, filter_in, sin_freq;
>>>
>>> saw_array =
>>> LFSaw.ar([1,0.99],[0,0.6],2000,2000).trunc([400,600])*[1,-1];
>>> filter_in =  Mix(saw_array);
>>> sin_freq = OnePole.ar(filter_in,0.98);
>>>
>>> SinOsc.ar(sin_freq).dup*0.1;
>>> }
>>> )
>>>
>>> And here is my variation on it to get this rolling:
>>>
>>> (
>>> play {
>>> var saw_array, filter_in, sin_freq, z;
>>>
>>> saw_array =
>>> LFSaw.ar([1,0.99],[0,0.6],20000,2000).trunc([400,600])*[1,-1];
>>> filter_in =  Mix(saw_array);
>>> sin_freq = OnePole.ar(filter_in,0.98);
>>> z = SinOsc.ar(sin_freq).dup*0.1;
>>>
>>> PitchShift.ar(z, 2, Line.kr(0.1,4,20).round, 0, 0.0001)
>>>
>>> }
>>> )
>>>
>>> The idea is to build upon or be inspired by the variation that I have
>>> done.
>>> Otherwise, there are no rules. The patch can be changed to whatever
>>> the next
>>> person wants to make it. The goal is to see what everyone can come up
>>> with
>>> and what sounds can be achieved by this process.
>>>
>>> Merry Christmas to all.
>>>
>>> Steve
>>> -- 
>>> View this message in context:
>>> http://n2.nabble.com/Patch-and-Variations-1-tp4215602p4215602.html
>>> Sent from the SuperCollider Users New (Use this!!!!) mailing list
>>> archive at Nabble.com.
>>>
>>> _______________________________________________
>>> sc-users mailing list
>>>
>>> info (subscription, etc.):
>>> http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
>>> archive: https://listarc.bham.ac.uk/marchives/sc-users/
>>> search: https://listarc.bham.ac.uk/lists/sc-users/search/
>>
>>
> 
> 
> _______________________________________________
> sc-users mailing list
> 
> info (subscription, etc.):
> http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
> archive: https://listarc.bham.ac.uk/marchives/sc-users/
> search: https://listarc.bham.ac.uk/lists/sc-users/search/
> 


_______________________________________________
sc-users mailing list

info (subscription, etc.): http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
archive: https://listarc.bham.ac.uk/marchives/sc-users/
search: https://listarc.bham.ac.uk/lists/sc-users/search/