|
Very enjoyable thread!
A full set of mentasm riffs should come with SC?
On 16 Jun 2009, at 16:19, Sharopolis wrote: Fantastic!
Mind if I put tis on my blog? Matt.
On Mon, Jun 15, 2009 at 10:26 PM, Wouter Snoei <mailinglists@xxxxxxxxxxxxxx> wrote: Hi Dan,
I've been messing around with this as well, inspired by your quest :-). I downloaded the alpha juno 2 manual and read there they use a combination of a pwm-able pulse and a saw waveform. It looks like this (2 cycles with 1/3 width):
{ LFSaw.ar( 200, 1 ).range(0,1) * (1-LFPulse.ar( 400, 0, 2/3 )) }.plot;
The wikipedia page on the hoover sound says it uses a kind of pwm that is unique to the juno series, and I think this is it. So here's my attempt (tweaked by ear):
(
SynthDef( "hoover", { |freq = 220, amp = 0.1, lgu = 0.1, lgd = 1, gate = 1|
var pwm, mix, env;
freq = freq.cpsmidi.lag(lgu,lgd).midicps;
freq = SinOsc.kr( { 2.9 rrand: 3.1 }!3, {2pi.rand}!3 ).exprange( 0.995, 1.005 ) * freq;
pwm = SinOsc.kr( {2.0 rrand: 4.0}!3 ).range(0.125,0.875);
// the saw/pulses
mix = (LFSaw.ar( freq * [0.25,0.5,1], 1 ).range(0,1)
* (1 - LFPulse.ar(freq * [0.5,1,2], 0, pwm))).sum * 0.1;
// the bass
mix = mix + LFPar.ar( freq * 0.25, 0, 0.1 );
// eq for extra sharpness
mix = BPeakEQ.ar( mix, 6000, 1, 3 );
mix = BPeakEQ.ar( mix, 3500, 1, 6 );
// kind of chorus
mix = mix + CombC.ar( mix.dup, 1/200,
SinOsc.kr( 3, [0.5pi, 1.5pi] ).range(1/300,1/200),
0.0 ) * 0.5;
env = EnvGen.kr( Env.asr, gate );
Out.ar( 0, mix * env * amp );
}).store;
)
(
p = Pmono(\hoover,
\dur, Pseq([0.25,0.5,7, 0.25]* 0.24, inf),
\lgu, 0.15,
\lgd, Pseq([ 0.1, 0.1, 1.5, 0.25], inf ),
\midinote, Pseq([20, 67, 62, 20] , inf)).play;
)
p.stop;
(
p = Pmono(\hoover, \dur, 0.24,
\lgu, 0.2,
\lgd, Pseq([1,1,2,0.5,2,2,2,2], inf ),
\midinote, Pseq([55, 40, 67, 55, 40, 55, 53, 52], inf)).play;
)
p.stop;
cheers,
Wouter
Op 15 jun 2009, om 10:37 heeft Dan Stowell het volgende geschreven: You know, I tried it with Pulse.ar at first and it just didn't sound
buzzy enough, but Saw sounded great, and the spectral profile matched
very well as well. Strange now I see that the original was apparently
made using pwm'ed square waves - maybe it's possible to get a better
re-creation using a pile of square waves at different octaves, but I
haven't hit that combination yet.
Dan
2009/6/15 Sharopolis <sharopolis@xxxxxxxxx>:
Just wondering,
What made you come to the conclusion that it was saw waves? I don't think
you mentioned that in your post.
Matt.
On Sun, Jun 14, 2009 at 6:15 PM, kernel <kernel@xxxxxxxxxxxxxxxxx> wrote:
Oh god what have you done - it took me years to get over the hoover sound.
I still hear it in my dreams.
Nice article, are you taking requests?
kernel
On 13 Jun 2009, at 09:50, Dan Stowell wrote:
Hi -
A little exercise in reverse-engineering an old synth sound:
http://www.mcld.co.uk/blog/blog.php?254
Dan
_______________________________________________
sc-users mailing list
info (subscription, etc.):
http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
archive: https://listarc.bham.ac.uk/marchives/sc-users/
search: https://listarc.bham.ac.uk/lists/sc-users/search/
_______________________________________________
sc-users mailing list
info (subscription, etc.):
http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
archive: https://listarc.bham.ac.uk/marchives/sc-users/
search: https://listarc.bham.ac.uk/lists/sc-users/search/
--
Why not SuperCollide on over to my SuperColliding Blog? It's about
SuperCollider!
http://superdupercollider.blogspot.com/
--
http://www.mcld.co.uk
_______________________________________________
sc-users mailing list
info (subscription, etc.): http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml
archive: https://listarc.bham.ac.uk/marchives/sc-users/
search: https://listarc.bham.ac.uk/lists/sc-users/search/
_______________________________________________ sc-users mailing list info (subscription, etc.): http://www.beast.bham.ac.uk/research/sc_mailing_lists.shtml archive: https://listarc.bham.ac.uk/marchives/sc-users/ search: https://listarc.bham.ac.uk/lists/sc-users/search/
--
Why not SuperCollide on over to my SuperColliding Blog? It's about SuperCollider!
http://superdupercollider.blogspot.com/
|