Re: [sc-users] SC code-remix contest

[Fredrik Olofsson <f@xxxxxxxxxxxxxxxxxxx>]

> We do SC code remix (modify) contest at Japanese-wiki.
> You can modify following code in anyway (except using non-SC 
> software). 


//'prepared' default synth /redFrik
(
var melody, bass, chord;

bass = Pbind(
	#[\midinote, \dur], Pseq([
		Pseq(#[[43, 3], [38, 3]]),
		Prand([
			Pseq(#[[43, 5], [38, 1]]),
			Pseq([Pn([43, 1], 4), [38, 2]]),
			Pseq([Pn([43, 1], 3), [38, 3]]),
			Pseq([Pn(Pseq(#[[43, 1.6], [43, 0.4]]), 2), #[38, 2]]),
			Pseq(#[[43, 3], [38, 1], [37, 1.6], [38, 0.4]]),
			Pseq(#[[43, 5.6], [38, 0.4]]),
			Pseq(#[[43, 1], [42, 1], [43, 1], [38, 2], [38, 1]])
		])
	], inf),
	\ctranspose, Pseq([Pn(-10, 24), Pn(-12, 24)], inf)
);

chord = Pbind(
	\dur, Pwrand([Pseq(#[1, 2]), Pseq(#[1.6, 1.4])], #[0.8, 0.2], inf),
	\midinote, Pseq(#[\, [59, 62, 66], \, [57, 61, 66]], inf)
		-Pwrand(#[48, -63], #[0.9, 0.1], inf)
);

melody = Pbind(
	\dur, Pseq([Pshuf(#[1, 1.6, 0.4, 1]), 1, Pshuf(#[1, 1.6, 0.4, 1]), 
Pseq(#[3, 12])], inf),
	\midinote, Pseq(#[\, 66, 69, 67, 66, 61, 59, 61, 62, 57, 54]+#[12, 0, 
1], inf)
		*Pstutter(11, Pseq(#[\, 2, 1.5, 2.5, 1, 3, 0.667], inf))
);

Ppar([bass, chord, melody]).play(TempoClock(2.8));
)



  #|
     fredrikolofsson.com     klippav.org     musicalfieldsforever.com
  |#